gdxdump1.gms : Use GdxDump NoData on Transportation Problem

Description

```Use GdxDump NoData option to create declarations for some GAMS Symbols

Contributor: M. Bussieck
```

Small Model of Type : GAMS

Category : GAMS Test library

Main file : gdxdump1.gms

``````\$Title  Use GdxDump NoData on Transportation Problem (GDXDUMP1,SEQ=504)

\$Ontext
Use GdxDump NoData option to create declarations for some GAMS Symbols

Contributor: M. Bussieck
\$Offtext

\$onecho > t.gms
Sets
i   canning plants   / seattle, san-diego /
j   markets          / new-york, chicago, topeka / ;

alias (i,ii);

Parameters

a(i)  capacity of plant i in cases
/    seattle     350
san-diego   600  /

b(j)  demand at market j in cases
/    new-york    325
chicago     300
topeka      275  / ;

Table d(i,j)  distance in thousands of miles
new-york       chicago      topeka
seattle          2.5           1.7          1.8
san-diego        2.5           1.8          1.4  ;

Scalar f  freight in dollars per case per thousand miles ;

Parameter c(i,j)  transport cost in thousands of dollars per case ;

Positive variables  x(i,j)  shipment quantities in cases ;
\$offecho
\$call gams t.gms lo=%gams.lo% gdx=t.gdx
\$if errorlevel 1 \$abort 'problems with creating data gdx file t.gdx'

\$call gdxdump t.gdx nodata > td.gms
\$if errorlevel 1 \$abort 'problems with gdxdump NoData'

\$include td

f = 90;
c(ii,j) = f * d(ii,j) / 1000 ;

Variable z;

Equations
cost        define objective function
supply(i)   observe supply limit at plant i
demand(j)   satisfy demand at market j ;

cost ..        z  =e=  sum((i,j), c(i,j)*x(i,j)) ;

supply(ii) ..   sum(j, x(ii,j))  =l=  a(ii) ;

demand(j) ..   sum(i, x(i,j))  =g=  b(j) ;

Model transport /all/ ;

Solve transport using lp minimizing z ;

Display x.l, x.m ;``````
GAMS Development Corp.
GAMS Software GmbH

General Information and Sales
U.S. (+1) 202 342-0180
Europe: (+49) 221 949-9170